// Skrolli 1/2015 esimerkkiohjelma: Vuoristomaisema Perlin-kohinalla
// Markku "Marq" Reunanen
// Julkaistu WTFPL-lisenssillä (http://www.wtfpl.net/about/)

final int XS=200, ZS=200;   // Ruudukon dimensiot

final float AMPLITUDE=50.0, // Maaston amplitudi
            EDIV     =20.0, // Kohinakoordinaattien jakaja
            HEIGHT   =-35,  // Maaston alin kohta
            WATER    =-15;  // Vedenpinnan korkeus

float elevation[][]=new float[XS][ZS],    // Korkeuskartta
      normal[][][] =new float[XS][ZS][3]; // Pinnan normaalit

void setup()
{
  size(1200, 600, P3D);
  noStroke();

  noiseSeed(17);        // Kohinan siemenluku - tämän poistamalla saa joka kerta eri maaston
  noiseDetail(6, 0.35); // Kohinan parametrit: kuusi oktaavia kertoimella 0.35
  
  // Lasketaan korkeuskartta ja normaalit Perlin-kohinalla
  for (int z=0; z<ZS; z++)
    for (int x=0; x<XS; x++)
    {
      elevation[x][z]=noise(float(x)/EDIV, float(z)/EDIV)*AMPLITUDE + HEIGHT;
      
      calcnormal(float(x)/EDIV, float(z)/EDIV, 1.0/EDIV, normal[x][z]);
    }
}

void draw()
{
  float scalefactor;
  
  background(50, 200, 255); // Taivaan väri

  translate(width/2, height/2); // Origo keskelle ruutua
  scale(1, -1, 1);              // Y-akseli ylöspäin kuten matemaattisissa koordinaateissa

  // Skaalataan maailmakoordinaatit ikkunan koosta riippumattomiksi
  scalefactor=float(width)/40.0;
  scale(scalefactor, scalefactor, scalefactor);

  lights();
  directionalLight(30, 30, 20, 1, -0.3, 0); // "Aurinko", suunnattu valo

  rotateY(float(frameCount)/500.0); // Pyöritetään maisemaa hitaasti

  // Piirretään vuoristo taulukosta kolmionauhoina
  ambient(50, 50, 50);
  fill(255, 255, 255);
  for (int z=0; z<ZS-1; z++) // Syvyyssuunta
  {
    beginShape(TRIANGLE_STRIP);

    for (int x=0; x<XS; x++) // Sivusuunta
    {
      normal(normal[x][z][0], normal[x][z][1], normal[x][z][2]); // Normaali ennen verteksiä
      vertex(float(x-XS/2), elevation[x][z], float(z-ZS/2));

      normal(normal[x][z+1][0], normal[x][z+1][1], normal[x][z+1][2]);
      vertex(float(x-XS/2), elevation[x][z+1], float((z+1)-ZS/2));
    }

    endShape();
  }

  // Riittävän suuri nelikulmio vedenpinnaksi
  ambient(0, 40, 180);
  fill(255, 255, 255, 200); // Hieman läpikuultava (viimeinen numero on alfa-kanava)
  beginShape(QUAD);
    vertex(-XS*2, WATER, ZS*2);
    vertex(XS*2,  WATER, ZS*2);
    vertex(XS*2,  WATER, -ZS*2);
    vertex(-XS*2, WATER, -ZS*2);
  endShape();
}

// Lasketaan annetulle maaston kohdalle (x,y) normaali vierekkäisistä pisteistä
void calcnormal(float x, float z, float diff, float n[])
{
  float nx=0,ny=0,nz=0, // Normaali
        dx,dy,dz,       // Delta-arvot eri suunnissa
        len;

  // Vasen-oikea
  dx=2;
  dy=(noise(x-diff, z)-noise(x+diff, z))*AMPLITUDE;
  nx=dy; 
  ny=dx;

  // Syvyyssuunta
  dz=2;
  dy=(noise(x, z-diff)-noise(x, z+diff))*AMPLITUDE;
  nz=dy;
  ny+=dz;

  // Normalisoidaan saatu vektori
  len=sqrt(nx*nx+ny*ny+nz*nz);
  n[0]=nx/len;
  n[1]=ny/len;
  n[2]=nz/len;
}